***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan 19, 2022                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P1CH13A A K
.param
+vc0 = 8.396e-11	 vc1 = 1.585e-11   	 vc2 = 1.107e0		 vc3 = 2.191e-12		 vc4 = 2.547e-1
+tc1 = 1.051e-2		 tc2 = 1.721e-2		 tc3 = 1.591e-2		 tc4 = 4.501e-2 
.func irexp(v) {(vc0+vc1*pwr(v,vc2))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter ***
+level = 1   
***** dc model parameter ***
+ is = 2.031e-15   	   n = 1.002		  rs = 1.500e-2
+ibv = 1e-3		 nbv = 1		  bv = 15.15
***** capacitance parameter ***
+cjo = 3.985e-10   	   m = 3.337e-1		  vj = 6.463e-1
+ fc = 0.5                      
***** temperature coefficient ***
+tnom = 25		  eg = 1.160		 xti = 3
+trs1 = 2e-3		tbv1 = 7.717e-4
.ends P1CH13A
*$
